move url parsing to utils method

src/invidious/helpers/utils.cr

@@ -389,3 +389,56 @@ def reduce_uri(uri : URI | String, max_length : Int32 = 50, suffix : String = "
   end
   return str
 end
+
+# Get the html link from a NavigationEndpoint or an innertubeCommand
+def parse_link_endpoint(endpoint : JSON::Any, text : String, video_id : String)
+  if url = endpoint.dig?("urlEndpoint", "url").try &.as_s
+    url = URI.parse(url)
+    displayed_url = text
+
+    if url.host == "youtu.be"
+      url = "/watch?v=#{url.request_target.lstrip('/')}"
+    elsif url.host.nil? || url.host.not_nil!.ends_with?("youtube.com")
+      if url.path == "/redirect"
+        # Sometimes, links can be corrupted (why?) so make sure to fallback
+        # nicely. See https://github.com/iv-org/invidious/issues/2682
+        url = url.query_params["q"]? || ""
+        displayed_url = url
+      else
+        url = url.request_target
+        displayed_url = "youtube.com#{url}"
+      end
+    end
+
+    text = %(<a href="#{url}">#{reduce_uri(displayed_url)}</a>)
+  elsif watch_endpoint = endpoint.dig?("watchEndpoint")
+    start_time = watch_endpoint["startTimeSeconds"]?.try &.as_i
+    link_video_id = watch_endpoint["videoId"].as_s
+
+    url = "/watch?v=#{link_video_id}"
+    url += "&t=#{start_time}" if !start_time.nil?
+
+    # If the current video ID (passed through from the caller function)
+    # is the same as the video ID in the link, add HTML attributes for
+    # the JS handler function that bypasses page reload.
+    #
+    # See: https://github.com/iv-org/invidious/issues/3063
+    if link_video_id == video_id
+      start_time ||= 0
+      text = %(<a href="#{url}" data-onclick="jump_to_time" data-jump-time="#{start_time}">#{reduce_uri(text)}</a>)
+    else
+      text = %(<a href="#{url}">#{text}</a>)
+    end
+  elsif url = endpoint.dig?("commandMetadata", "webCommandMetadata", "url").try &.as_s
+    if text.starts_with?(/\s?[@#]/)
+      # Handle "pings" in comments and hasthags differently
+      # See:
+      #  - https://github.com/iv-org/invidious/issues/3038
+      #  - https://github.com/iv-org/invidious/issues/3062
+      text = %(<a href="#{url}">#{text}</a>)
+    else
+      text = %(<a href="#{url}">#{reduce_uri(url)}</a>)
+    end
+  end
+  return text
+end